Microsoft Excel:
  Таблицы и VBA. Справочник.
  Вопросы и Ответы. Советы. Примеры.
Меню Заметки | Как вывести в ячейке название дня

Rambler's Top100


Counter CO.KZ

Вариант I.
Для достижения нужного результата можно использовать возможности, которые предоставляются при использовании собственных, т.е. пользовательских форматов. В данном случае, нас интересует только один формат, а именно ДДДД

Выделите нужную ячейку или диапазон ячеек в рабочем листе, которые содержат даты (допускается выделение несмежных ячеек и диапазонов) Затем в меню Формат выберите команду Ячейки, нажмите на закладку Число и в поле Числовые форматы выберите (все форматы), в поле Тип введите ДДДД и нажмите кнопку ОК.

Комментарий :
важно Этот вариант позволяет получить только визуальное представление дня, т.е. на самом деле ячейка по-прежнему содержит дату, и эти даты могут участвовать в вычислениях.
В случае, когда необходимо получить именно текст, следует использовать следующие варианты.


Вариант II.
Для получения название дня в виде текста можно воспользоваться стандартной функцией рабочего листа =ТЕКСТ() которая преобразует дату в текст с учётом указанного формата.

=ТЕКСТ($A$1;"ДДДД")

Совет : Для того, чтобы день недели начинался с прописной буквы можно использовать формулу :

=ПРОПНАЧ(ТЕКСТ($A$1;"ДДДД"))


Вариант III.
Для получения название дня можно воспользоваться стандартными функциями рабочего листа =ВЫБОР() и =ДЕНЬНЕД() Первая функция используется для того, чтобы возвратить одно значение из списка, используя его индекс(номер), а номер определяется с помощью второй функции, которая возвращает день недели (число от 1 до 7) для указанной даты.

=ВЫБОР(ДЕНЬНЕД($A$1;2);"Понедельник";"Вторник";"Среда"; "Четверг";"Пятница";"Суббота";"Воскресенье")


Вариант IV.
Для получения название дня в виде текста можно воспользоваться стандартными функциями рабочего листа =ИНДЕКС() и =ДЕНЬНЕД() Первая функция используется для того, чтобы возвратить один из элементов массива, используя его индекс(номер), а нужный номер определяется с помощью второй функции, которая возвращает день недели (число от 1 до 7) для указанной даты.

=ИНДЕКС({"Понедельник";"Вторник";"Среда";"Четверг"; "Пятница";"Суббота";"Воскресенье"};ДЕНЬНЕД($A$1;2))


Вариант V.
Тот же самый способ, что и предыдущий, но перечень всех дней недели должен располагаться в ячейках рабочего листа, в данном случае - в диапазоне B1:B7

=ИНДЕКС($B$1:$B$7;ДЕНЬНЕД($A$1;2))


Вариант VI.
Для получения название дня, можно воспользоваться уже известными стандартными функциями рабочего листа, только массив дней будет представлять именованную формулу.

В меню Вставка выберите пункт Имя, далее выберите команду Присвоить. В диалоговом окне Присвоение имени в поле Имя введите нужное имя, например ДНИ, а в поле Формула введите :

={"Понедельник";"Вторник";"Среда";"Четверг"; "Пятница";"Суббота";"Воскресенье"}

и нажмите кнопку ОК.

После создания именованной формулы, выделите нужную ячейку или диапазон ячеек в рабочем листе и введите формулу, которая будет использовать созданное Вами имя :

=ИНДЕКС(ДНИ;ДЕНЬНЕД($A$1;2))


Вариант VII.
Тот же самый способ, что и предыдущий, но именованная формула будет представлять собой не массив дней, а всю формулу целиком.

В меню Вставка выберите пункт Имя, далее выберите команду Присвоить. В диалоговом окне Присвоение имени в поле Имя введите нужное имя, например ДЕНЬ_ИМЯ, а в поле Формула введите :

=ИНДЕКС({"Понедельник";"Вторник";"Среда";"Четверг"; "Пятница";"Суббота";"Воскресенье"};ДЕНЬНЕД($A$1;2))

и нажмите кнопку ОК.

После создания именованной формулы, выделите нужную ячейку или диапазон ячеек в рабочем листе и введите формулу, которая будет использовать созданное Вами имя :

=ДЕНЬ_ИМЯ

Предполагается, что :
  • Ячейка A1 содержит значение даты [вариант II - VII]
  • Ячейки диапазона B1:B7 содержат названия всех дней недели [вариант V]


    Примеры можно скачать здесь


    Вопросы, которые связаны с этой темой
  • Как выделить несмежный диапазон ячеек ?
  • Как создать свой собственный пользовательский формат ?
  • Как быстро ввести формулу сразу в несколько ячеек ?



    • Автор : Климов Павел Юрьевич
    • © 2004-2016 Климов П.Ю. Все права защищены. WebDesign & Error's Klimoff